using qsort to sort one array based on another array?

valueArr = #() -- declare here so it can be seen by functions
  fn sortFn a b = if valueArr[a] > valueArr[b] then 1 else -1
  fn sortPoints pointArr =
   (
   	   indexArr = for i = 1 to pointArr.count collect i -- collect the indices, these are what we sort
   	   valueArr = for p in pointArr collect (cos p.x + sin p.y) -- compute a value to sort by
   	   qsort indexArr sortFn -- sort the indices
   	   for i = 1 to pointArr.count collect pointArr[indexArr[i]] -- return the points sorted by index
   )

valueArr = #() -- declare here so it can be seen by functions
   -- here's the part I don't know how to do: getting the index of a or b
   fn sortFn a b = if valueArr[(index of a)] > valueArr[(index of b)] then 1 else -1
   fn sortPoints pointArr =
   (
   	  valueArr = for p in pArr collect (cos p.x + sin p.y) -- compute some value to sort by
   	  qsort pointArr sortFn -- sort the actual point array
   )

 -- make a buffer, for example:
 seed 0
 data = for k=1 to 100000 collect 
 (
 	d = random [-180,-180] [180,180]
 	cs = (cos d.x) + (sin d.y)
 	#(d, cs)
 )
 -- sort by sincos
 fn sortByN2 a b = if a[2] < b[2] then -1 else if a[2] > b[2] then 1 else 0 
 qsort data sortByN2 
 final = for d in data collect d[1]
 

fn sortbybuffer a b buffer: = if buffer[a] < buffer[b] then -1 else if buffer[a] > buffer[b] then 1 else 0
qsort data sortbybuffer buffer:other_array

fn power a b = pow a b
fn sortwithfunction a b fun:  =
(
	 d1 = fun a b 
 	 d2 = fun b a
	 if d1 < d2 then -1 else  if d1 > d2 then 1 else 0
)
qsort data sortwithfunction fun:power