Need help determining vertex normals

[SyncViewS]

Hi Nicolas and welcome,
I guess the simplest way to get vert normals is to average normals from faces sharing them:

(
local oSphere = convertToPoly(Sphere())
local iVert = 26 -- just choose a vert
polyOp.setVertSelection oSphere iVert -- just to have a visual clue, unneeded

local baVertFaces = polyOp.getFacesUsingVert oSphere iVert
local p3VertNormal = [0,0,0]

-- Note: It's better to collect all face normals before computing vert normals. See following point 3.

for iFace in baVertFaces do
p3VertNormal += polyOp.getFaceNormal oSphere iFace

p3VertNormal = normalize(p3VertNormal)
print p3VertNormal
)
There are other ways, that weight vert normals about face angles, dimensions and so on.
Take a look at 3ds Max 2009 SDK Help (http://usa.autodesk.com/adsk/servlet/item?siteID=123112&id=7481368) under: "Computing Face and Vertex Normals".


I got some hints by reading your code. Some of them are just a question of taste, other could improve your code.

1. Unless you need ordered indexes, use BitArrays rather than Arrays, it's much faster.

verticesFace = #() -- Array
verticesFace = polyOp.getFaceVerts legoMesh face

-- use: polyOp.getVertsUsingFace <Poly poly> <int face>
verticesFace = #{} -- BitArray
verticesFace = polyOp.getVertsUsingFace legoMesh face

2. Do not take an array only to get the number of its elements if there are straight methods:

verticesFace = polyOp.getFaceVerts legoMesh face
numberOfVerticesFace = verticesFace.count
for vertex = 1 to numberOfVerticesFace do ( ... )

-- use: polyOp.getFaceDeg <Poly poly> <int face>
numberOfVerticesFace = polyOp.getFaceDeg legoMesh face
for vertex = 1 to numberOfVerticesFace do ( ... )

3. Do not get position for the same vert more than once, polyOp.getVert is a quite heavy task. Store all verts position in a Point3 Array then access it. Same goes for uvMapVerts

for vertex = 1 to numberOfVerticesFace do (
position = polyop.getvert legoMesh verticesFace[vertex]
...
)

-- becomes:
local iNumVerts = polyOp.getNumVerts LegoMesh

local ap3VertsPos = #() -- Array
ap3VertsPos[iNumVerts] = [0,0,0] -- size initialization

for iVert = 1 to iNumVerts do (
ap3VertsPos[iVert] = polyOp.getVert LegoMesh iVert
)
-- or:
ap3VertsPos = for iVert = 1 to iNumVerts collect (polyOp.getVert LegoMesh iVert)

-- assuming verticesFace is an Array storing ordered list of verts in a face
for vertex = 1 to numberOfVerticesFace do (
position = ap3VertsPos[verticesFace[vertex]]
...
)


4. Do not query the count of an array to iterate over its elements. Use for...in...do, it's faster.

-- previous loop becomes:
for vertex in verticesFace do (
position = ap3VertsPos[vertex]
...
)
-- works with Arrays and BitArrays

5. Avoid declaring static object names into your code without a check.
mountHead = $MountHead

-- becomes:
if (selection[1].name == "MountHead") then ( mountHead = selection[1] )

It's better to have a pickButton to point to scene geometry, maybe with a filter function.

-- to filter object with that name, not particularly smart anyway, but you can set it as you like
function filterMesh = (selection[1].name == "MountHead")

pickButton pbtGetMesh "getMesh" message:"Pick the Mesh to Export" filter:filterMesh autoDisplay:true

-- and later in the code:
if (mountHead != undefined) then ( ... )
-- becomes:
if (pbtGetMesh.object != undefined) then ( ... )

6. If there are long operations giving feedback only at the end of processing consider using a ProgressBar to show the computer is not frozen.

7. Not required since variables declared inside a MacroScript are local to it, but it nicer to specify it with a "local".

Putting all this buzzing code chat aside, nice MaxScript start!

- Enrico

[afie9329]

Thank you SyncViewS for the very informative reply. Much appreciated. I haven't been able to test your solution for the exact same reason it took me a while to answer your post. I'm waiting for my computer to be repaired. I'll let you know how it turns out. Thanks again.

[galagast]

Splendid maxscripting tips you got there. These would be a good addition to the "How to Make It Better?" category in the maxscript helpfile. Thank you SyncViewS! :)

[CGTalk Moderation]

This thread has been automatically closed as it remained inactive for 12 months. If you wish to continue the discussion, please create a new thread in the appropriate forum.