Collecting BitmapTextures in Scene (m.filename == "")

[ZeBoxx2]

The biggest problem you're running into is that you are collecting 'n' in the 2nd line. 'n' is your loop counter, so you're just collecting numbers - not the references themselves.
Thus in the third line, the classof for that 'reference' will always be (in this case) integer :)


NONEBitmaps = for m in (getClassInstances BitmapTexture) where (m.filename == "") collect ( m )
dependentRefs = for noneBmp in NONEBitmaps collect ( refs.dependents noneBmp )
for i = 1 to dependentRefs.count do (
refs = dependentRefs[i]
newrefs = for r in refs where ((superClassOf r == material) OR (classOf r == Material_Editor)) collect ( r )
dependentRefs[i] = newrefs
)
-- now you've got two arrays...
-- NONEBitmaps that holds the bitmaps
-- dependentRefs that, for each bitmap, holds the valid references
-- where 'valid' means it's either a material, or the material editor (not library(!))
-- let's print the results out
for i = 1 to NONEBitmaps.count do (
format "Dependents for '%':\n" noneBitmaps[i]
for j = 1 to dependentRefs[i].count do (
format "\t%\n" dependentRefs[i][j]
)
)


However, I should 'warn' you, that getClassInstances doesn't always get all the required results (sure wish it would)... it will work on materials assigned to objects and the like, but good luck getting e.g. a Blur render effect's mask bitmap using getClassInstances.

Neil Blevins has functions in his soulburn library that loop over a scene in a more thorough manner that you might be able to use instead, if the above is a concern.

[MikeOwen]

Thanks Richard!

[CGTalk Moderation]

This thread has been automatically closed as it remained inactive for 12 months. If you wish to continue the discussion, please create a new thread in the appropriate forum.