making UI, some queries are not working

[YourDaftPunk]

What you needed to do was read the text field after the button was pressed. Here's a good way to do it:
proc createMultiplyDivideNode() {
string $baseName = `textFieldGrp -q -text "nameAndLabel"`;
createNode multiplyDivide -n ($baseName + "_md_utl");
}


global proc utilWin(){
if(`window -exists "utilWin"`){
deleteUI -window "utilWin" ;
};

//layout
window -title "utility Creator" "utilWin" ;
columnLayout -width 318 -height 200 "mainLay" ;
frameLayout -collapsable false -width 318 -height 200 -borderVisible true -borderStyle "etchedIn" -marginWidth 6 -marginHeight 8 -label "NodeSetup" "nodeLay" ;
columnLayout "nodeSetup";
// fieldGroup
textFieldGrp -label "baseName" -columnWidth 1 64 -columnWidth 2 236 "nameAndLabel" ;
// utility buttons
rowColumnLayout -numberOfColumns 3 "buttons" ;
button -label "multiplyDivide" "mdBtn" ;
button -label "condition" "condBtn" ;
button -label "unitConversion" "ucBtn" ;
button -label "plusMinusAverage" "pmaBtn" ;
button -label "curveInfo" "ciBtn" ;
button -label "reverse" "revBtn" ;
button -label "distBetween" "distBtn" ;
button -label "setRange" "srBtn" ;
button -label "clamp" "cutBtn" ;
button -label "blendTwoAttr" "b2aBtn" ;
button -label "blendColors" "bcBtn" ;
button -label "vectorProduct" "vpBtn" ;
setParent.. ;
setParent.. ;
setParent.. ;
setParent..;
setParent.. ;

button -edit -command "createMultiplyDivideNode" "mdBtn" ;
showWindow "utilWin" ;
window -edit -widthHeight 334 300 "utilWin" ;
}

I just changed your button command to: button -edit -command "createMultiplyDivideNode" "mdBtn" ; and had it call a new procedure- createMultiplyDivideNode. At that point the user has entered text so we can query the textFieldGrp and run createNode. Simple. Since your multiplyDivide node creation is now seperate, you can cleanly add some error checking into the code- did the user really enter a name? Does the node you are about to create already exist? If so, should your code rename it to prevent a collision or should you let the createNode command append a number to the name? It's up to you- either way, now you've got your interface separate from your logic, which is a very good thing.

-shawn

[mlefevre]

Hey there,

I changed your code slightly. I'm not sure what your error was down to, perhaps it was when you were using the ' ' characters. I replaced them with \" instead.

I added a separate procedure that queries the textfield. It takes in two arguments, the name of the node your creating, and the suffix for that particular node. This way, you can place the two arguments in each button command, so you only need the one procedure.

Hope that helps,
Good luck!

-matt


*EDIT - daftPunk's beat me too it ;) hehe


global proc makeNode(string $node, string $suffix){

string $baseName = `textFieldGrp -q -text nameAndLabel`;
createNode $node -n ($baseName + $suffix);
};


global proc utilWin(){
if(`window -exists utilWin`)
deleteUI utilWin;

//layout
window -title "utility Creator" utilWin;
columnLayout -width 318 -height 200 "mainLay" ;
frameLayout -collapsable false -width 318 -height 200 -borderVisible true -borderStyle "etchedIn" -marginWidth 6 -marginHeight 8 -label "NodeSetup" "nodeLay" ;
columnLayout "nodeSetup";
// fieldGroup
textFieldGrp -label "baseName" -columnWidth 1 64 -columnWidth 2 236 "nameAndLabel" ;
// utility buttons
rowColumnLayout -numberOfColumns 3 "buttons" ;
button -label "multiplyDivide" -c "makeNode(\"multiplyDivide\", \"_md_utl\")" mdBtn;
button -label "condition" -c "makeNode(\"condition\", \"_cdn_utl\")" condBtn;
button -label "unitConversion" "ucBtn" ;
button -label "plusMinusAverage" "pmaBtn" ;
button -label "curveInfo" "ciBtn" ;
button -label "reverse" "revBtn" ;
button -label "distBetween" "distBtn" ;
button -label "setRange" "srBtn" ;
button -label "clamp" "cutBtn" ;
button -label "blendTwoAttr" "b2aBtn" ;
button -label "blendColors" "bcBtn" ;
button -label "vectorProduct" "vpBtn" ;
setParent.. ;
setParent.. ;
setParent.. ;
setParent..;
setParent.. ;

showWindow utilWin;

};

utilWin();

[Leionaaad]

thank you people, now I got the general idea. :bounce:

[CGTalk Moderation]

This thread has been automatically closed as it remained inactive for 12 months. If you wish to continue the discussion, please create a new thread in the appropriate forum.