Daylight System Time Controller giving odd results

[TzMtN]

try this:
$Daylight01.controller.solar_time.controller.value

[LoneRobot]

hi matan, thanks for your reply.


i didnt realise that subanim was a controller from the MXs help, it looks like a property that returns a float value. however, while it says it returns a float it follows with "The solar time expressed as an integer value of seconds since midnight." :shrug:

however, im using your method I get a float value but not what i expect from the related function .

example time - 16hrs 36mins 23 secs

fn TimeFromSolarTime solar_time =
(
hrs = int(solar_time/3600.0) -- full hours in the solar_time value
min = int((solar_time - hrs*3600.0)/60.0) -- full minutes in the difference between the full time and the full hours
sec = int(solar_time - hrs*3600.0 - min*60.0 + 0.5) -- full seconds in the rest of the value
#(hrs,min,sec) -- return the result as a 3 elements array
)

-- output
$daylight01.controller.solar_time.controller.value
16.6064
TimeFromSolarTime 16.6064
#(0, 0, 17)

in any case it's not the number of seconds since midnight as per the MXS help, as for the above time it would be 218183? is it that the 16.6064 value apears to be a decimal representation of the time itself rather than elapsed seconds?

[TzMtN]

try this function:
fn TimeFromSolarTime solarTime =
(
local timeInSecs = solarTime * 3600
local hrs = solarTime as integer
local minsAndSecs = mod timeInSecs 3600
local min = (minsAndSecs / 60) as integer
local sec = (mod minsAndSecs 60) as integer
print ("the time is: " + hrs as string + " hours, " + min as string + " minutes and " + sec as string + " seconds.")
#(hrs,min,sec)
)

[LoneRobot]

thanks matan! so when I have to set the time i do it as a decimal fraction of the minutes and seconds.

[TzMtN]

the reverse function is as easy as this:
fn solarTimeFromTime hrs min sec =
(
hrs + min / 60.0 + sec / 3600.0
)

[LoneRobot]

now that's the sort of maths i like! thanks matan!

[CGTalk Moderation]

This thread has been automatically closed as it remained inactive for 12 months. If you wish to continue the discussion, please create a new thread in the appropriate forum.