PDA

View Full Version : Hypergraph Issues


designingpatrick
04-20-2008, 11:05 PM
For one reason or another, my utility render nodes like to disapear in the hypergraph, I don't know how to locate them otherwise. So if create a node, deselect it and reframe the hypergraph, it is gone. It seems like if it is not connected to anything, then it will dissapear when the screen refreshes.

digitalandrew
04-22-2008, 12:26 PM
Hi, I know what you mean. This is a tool I wrote to ease that problem...

global proc amb_createNodeUI() {
if (` window -q -ex amb_createNode_UI` == 1) { deleteUI amb_createNode_UI; }

string $amb_scrollSel[];

window -t "Utility nodes" -s 0 amb_createNode_UI;
formLayout amb_form;
tabLayout amb_tabLayout;
frameLayout -lv 0 amb_createLayout;
columnLayout -adj 1;
textScrollList -nr 16 amb_nodeList_ctrl;
textFieldButtonGrp -l "Name" -tx "" -bl "Create" -bc "amb_createNode(); amb_listNodes(0);" -cw3 50 147 22 amb_nodename_ctrl;
setParent ..;
setParent ..;

frameLayout -lv 0 amb_existLayout;
columnLayout -adj 1;
textScrollList -nr 16 -sc "$amb_scrollSel = ` textScrollList -q -si amb_exList_ctrl`; select -r $amb_scrollSel[0]; clear $amb_scrollSel;" amb_exList_ctrl;
button -l "Refresh" -c "amb_listNodes(1)";

formLayout -e -af amb_tabLayout "top" 0 -af amb_tabLayout "left" 0 -af amb_tabLayout "bottom" 0 -af amb_tabLayout "right" 0 amb_form;
tabLayout -e -tl amb_createLayout "Create" -tl amb_existLayout "Existing" amb_tabLayout;

amb_listNodes(0);

window -e -wh 250 330 amb_createNode_UI;
showWindow amb_createNode_UI;
}

global proc amb_createNode() {
string $amb_nodetype[] = ` textScrollList -q -si amb_nodeList_ctrl`;
string $amb_nodename = ` textFieldButtonGrp -q -tx amb_nodename_ctrl`;

if ($amb_nodetype[0] != "") {
if ($amb_nodename == "") { $amb_nodename = ` createNode $amb_nodetype[0]`; } else { createNode -n $amb_nodename $amb_nodetype[0]; }
textFieldButtonGrp -e -tx "" amb_nodename_ctrl;
} else {
error "Node type not selected.\n";
}

clear $amb_nodetype;
}

global proc amb_listNodes(int $amb_mode) {
// add more to the end of this array if nessacary...
string $amb_nodeArray[] = { "condition", "multiplyDivide", "plusMinusAverage", "reverse", "distanceBetween", "samplerInfo", "vectorProduct", "frameCache", "motionPath" };

textScrollList -e -ra amb_nodeList_ctrl;
textScrollList -e -ra amb_exList_ctrl;

if ($amb_mode == 1) { tabLayout -e -sti 2 amb_tabLayout; }

for ($amb_item in $amb_nodeArray) {
textScrollList -e -a $amb_item amb_nodeList_ctrl;
$amb_allNodeList = ` ls -typ $amb_item`;
for ($amb_lsItem in $amb_allNodeList) { textScrollList -e -a $amb_lsItem amb_exList_ctrl; }
}

clear $amb_nodeArray;
}

amb_createNodeUI();


Hope it helps.
-andrew

sj_bee
04-23-2008, 12:41 PM
Or you could right click in the outliner and uncheck "Show DAG Objects Only". This will show all the nodes in the scene, including render nodes, and you can just select them there.

CGTalk Moderation
04-23-2008, 12:41 PM
This thread has been automatically closed as it remained inactive for 12 months. If you wish to continue the discussion, please create a new thread in the appropriate forum.