PDA

View Full Version : multi-column rollout?


bhnh
03-30-2008, 06:53 PM
I'm working on a rollout that's getting mighty tall. Is it possible to split a rollout into two or more columns? Many thanks.

abyjoe
03-30-2008, 08:00 PM
dont you like the scrolling rollout like the render to texture dialog. its a standard feature.... if you are using groups in your rollouts then set the height of the main rollout window to what u want (smaller) and u will get the scrolling rollout.

Bobo
03-30-2008, 08:08 PM
I'm working on a rollout that's getting mighty tall. Is it possible to split a rollout into two or more columns? Many thanks.

In addition to my Area answer, here is an example:

(
global masterRollout
try(destroyDialog masterRollout)catch()
rollout childRollout01 "First Rollout"
(
button btn_button01 "Button01" width:170
button btn_button02 "Button02" width:170
button btn_button03 "Button03" width:170
button btn_button04 "Button04" width:170
button btn_button05 "Button05" width:170
)
rollout childRollout02 "Second Rollout"
(
button btn_button01 "Button01" width:170
button btn_button02 "Button02" width:170
button btn_button03 "Button03" width:170
button btn_button04 "Button04" width:170
button btn_button05 "Button05" width:170
button btn_button06 "Button06" width:170
)
rollout childRollout03 "Third Rollout"
(
spinner spn_spinner01 "Spinner01" fieldwidth:80
spinner spn_spinner02 "Spinner02" fieldwidth:80
spinner spn_spinner03 "Spinner03" fieldwidth:80
spinner spn_spinner04 "Spinner04" fieldwidth:80
spinner spn_spinner05 "Spinner05" fieldwidth:80
spinner spn_spinner06 "Spinner06" fieldwidth:80
spinner spn_spinner07 "Spinner07" fieldwidth:80
)

rollout masterRollout "Master Rollout"
(
subRollout sub_rollout01 width:200 height:200 across:2 align:#left offset:[-10,0]
subRollout sub_rollout02 width:200 height:200 align:#right offset:[10,0]
on masterRollout open do
(
addSubRollout sub_rollout01 childRollout01
addSubRollout sub_rollout01 childRollout02 rolledup:true
addSubRollout sub_rollout02 childRollout03
)
)
createDialog masterRollout 410 210
)

http://www.scriptspot.com/bobo/stuff/forum/twocolumnsrollout.gif

bhnh
03-30-2008, 08:47 PM
Wow. More than I deserve. Many thanks, Bobo.

bhnh
03-31-2008, 12:21 PM
OK, here's something I slapped together in the Visual Editor. Interesting alternative, though for what I'm doing I think I prefer collapsible rollouts in a floater. Thanks again.

http://www.e-nimation.com/turbosquid/doubleColumnRollout.gif

CGTalk Moderation
03-31-2008, 12:21 PM
This thread has been automatically closed as it remained inactive for 12 months. If you wish to continue the discussion, please create a new thread in the appropriate forum.