dividing polygon edge by verts.

[HalfVector]

I don't know MeshTools and I don't know if this is the best way to do that, but...

try ( destroyDialog roDivideEdge ) catch ()

rollout roDivideEdge "Divide Edge" (
spinner spnDivs "Divide by " range:[2,1000,2] type:#integer
button btnDivide "Divide"

fn divideEdge poly edge divs = (
local nVerts = divs - 1
for div = 1 to nVerts do (
local frac = 1.0 / (divs as Float)
local newVert = polyOp.divideEdge poly edge frac
local edges = (polyOp.getEdgesUsingVert poly newVert) as Array
if edges[1] == edge then edge = edges[2] else edge = edges[1]
divs -= 1

)
)

on btnDivide pressed do (
if selection.count == 1 do (
if (classOf selection[1]) == Editable_Poly do (
local edgeSel = polyOp.getEdgeSelection selection[1] as Array
if edgeSel.count > 0 do (
for edge in edgeSel do (
divideEdge selection[1] edge spnDivs.value
)
)
)
)
)
)

createDialog roDivideEdge

It divides an edge (or a selection of edges) a specified number of times. The vertices are spaced evenly along the edge. The most important thing in this script is the funcion divideEdge.

I didn't test it much so could have errors!.

Hope that helps.

[cyfer]

thanks a lot

that was quick !!

i'm gonna test it to see what it brings out

thanks

[CGTalk Moderation]

This thread has been automatically closed as it remained inactive for 12 months. If you wish to continue the discussion, please create a new thread in the appropriate forum.