Fast way to name diffuseMap for mutiple textures

[Bobo]

When you try to assign to a selection of faces, Max tries to automatically create a MultiSub material. How about changing the face material IDs via the script, then simply generating a MultiMaterial() material with 12 sub-materials, assigning a texture to each sub-material diffuse slot, then assigning the MultiMaterial to the plane?

In that case, the object must not even be selected in the Modify panel to do the job!

Of course, in your case, you could rename the maps and materials BEFORE assigning them.
Also, is baseMap an INSTANCE of the same bitmap? I would expect that you would assign a unique one to each material...

[Bobo]

When you try to assign to a selection of faces, Max tries to automatically create a MultiSub material. How about changing the face material IDs via the script, then simply generating a MultiMaterial() material with 12 sub-materials, assigning a texture to each sub-material diffuse slot, then assigning the MultiMaterial to the plane?


Here is an example:


theBitmapFiles = #("","","","","","","","","","","","") --enter the bitmap paths here!
p = plane lengthsegs:3 widthsegs:4 --create a plane with 12 segs
convertToPoly p --make it a polygonal mesh
for f = 1 to 12 do polyOp.setFaceMatID p f f --set each poly to different MatID
theMat = multiMaterial numsubs:12 --create a Multi/Sub material with 12 slots
for f = 1 to 12 do --go through them
(
theName = ("Car" + (if f < 10 then "0" else "") + f as string) --define the name
theSubMat = standard name:theName diffuse:(random black white) --create a standard material
theSubMat.diffusemap = bitmaptexture name:theName filename:theBitmapFiles[f] --assing a bitmap texture with same name and path from the array
theMat[f] = theSubMat --assing to the f-th slot of the Multi/Sub material
)
p.material = theMat --assing the Multi/Sub to the object
-- because the diffuse colors were randomized, you should see 12 color faces on the plane
-- add the paths to the array in the beginning and the bitmaps will be assigned...

[erilaz]

Thanks Bobo! That's far more straightforward!:D

[erilaz]

Still one small problem. I assign the first material in the multisub to be the original texture I want to base the names off, and there's no problem there. When I go through and do the loop to create the materials and diffuseMaps though, the original diffuseMap name of the first texture gets renamed to the last diffuseMap in the series. Am I instancing somewhere by mistake?

[Bobo]

Still one small problem. I assign the first material in the multisub to be the original texture I want to base the names off, and there's no problem there. When I go through and do the loop to create the materials and diffuseMaps though, the original diffuseMap name of the first texture gets renamed to the last diffuseMap in the series. Am I instancing somewhere by mistake?

I am pretty sure you are instancing - I mentioned it in another post.
If you are using a base map to create all sub-maps, you would have to assign COPIES of that map, not instances. Just use the COPY function in front of the bitmap on the right hand side of the assignment. Using the original bitmap stored in the variable will ALWAYS assign as instance (this is the implicit behaviour when assinging materials, maps, modifiers etc. from a class instance stored in a variable - you always get an instance! No wonder these objects are called "class instances" ;) )

[CGTalk Moderation]

This thread has been automatically closed as it remained inactive for 12 months. If you wish to continue the discussion, please create a new thread in the appropriate forum.