whow to do delete meshsmooth?

[Bobo]

ok here is my question I want to delete meshsmooth with a script


select $'Panther Med Mouth'
deleteModifier $ 2

meshsmooth is in level two

but the problem is if someone run another time the script in level 2 will be another modifier that wil be deleted.

if anyway to make a script that checks if is a meshmooth and later delete this or if is not a meshmooth doesnt do anything .

is eassy to do or can i know nay website to tell me how to do it.


The following script removes the TOP MOST MESHSMOOTH from the stack of any selected objects:

macroScript delTopMS category:"CGTalk"
(
for obj in selection do
(
for i = 1 to obj.modifiers.count do
(
if classof obj.modifiers[i] == Meshsmooth do
(
deleteModifier obj i
exit
)--end if
)--end i loop
)--end obj loop
)--end macro


The following macroscript deletes ALL MESHSMOOTH modifiers from all selected objects:

macroScript delAllMS category:"CGTalk"
(
for obj in selection do
for i = obj.modifiers.count to 1 by -1 do
if classof obj.modifiers[i] == Meshsmooth do
deleteModifier obj i
)--end macro

[luigi]

thanks alot bobo i try to put on my scene.

in my case i only want to affect a mesh call character

i hope i can know how actualize your script for only affect this mesh.

i will post when i get it working

thanks a lot:).

[CGTalk Moderation]

This thread has been automatically closed as it remained inactive for 12 months. If you wish to continue the discussion, please create a new thread in the appropriate forum.