Select faces by material

[Marcel]

Ok, I've put something together that sorta works, but it is very clumsy. Who can point me to a better way to do this?

////////////////////////////

// select objects from scene
string $objectName[] = `ls -sl -fl`;

// get first object
$newObject = $objectName[0];
$newMaterial = "wall";

string $newList[];
clear $newList;

// select all faces with material
hyperShade -objects $newMaterial;
string $faceList[] = `ls -selection -flatten`;
int $numberOfFaces = size($faceList);


for ($v=0; $v<$numberOfFaces; $v++)
{
// strip to objectname only
string $faceExtension = "." + match("[^\.]*$", $faceList[$v]);
string $test = substring($faceList[$v], 1, size($faceList[$v]) - size($faceExtension));

// if object is from selected object put face path to array
if($test == $newObject)
{
$sizeNewList = size($newList);
$newList[$sizeNewList] = $faceList[$v];
}
}

select -r $newList;

[sbp]

Hi,

first select all of the target object's faces either by mouse or mel then use

string $tempset = `sets`;
string $tempgrps[] = `listConnections -type shadingEngine blinn1`;
select `sets -int $tempset $tempgrps[0]`;


substitue blinn1 for whatever material you're looking for.

[Marcel]

aaah, that's the kind solution I was looking for, thanks! :)

[CGTalk Moderation]

This thread has been automatically closed as it remained inactive for 12 months. If you wish to continue the discussion, please create a new thread in the appropriate forum.