Select layers by prefix name

[martinez]

It's a little weird, but nodes isn't a property of a layer. It's a function that assigns the array of nodes to a variable.

Also, you'll want to use JOIN instead of APPEND since the select command doesn't like arrays inside of arrays.


fn selectLayerPrefix str =
(
local objArray = #()

for i= 1 to (LayerManager.count-1) where
(
matchpattern (LayerManager.getLayer i).name pattern:(str+"*")
)
do
(
(LayerManager.getLayer i).nodes &theNodes
join objArray theNodes
)

select objArray

)

selectLayerPrefix "LGT_"

[phantomx]

nice explanation, it's working like a charm!
Thanks!

[coolankur49]

I was searching something like this only. :)

[PixelBaker]

A shorter version would be:


function selectNodesInsideLayerWithPrefix inPrefix =
(
local nodesInsideLayerWithPrefix = for nodeOn in objects where matchPattern nodeOn.layer.name pattern:(inPrefix +"*") collect nodeOn
if nodesInsideLayerWithPrefix.count > 0 then
select nodesInsideLayerWithPrefix
else
clearSelection()
)

selectNodesInsideLayerWithPrefix "LGT_"

[denisT]

if a function selects something by a condition it has to clear selection if nothing meets the criteria.

if list.count > 0 then select list else clearselection()

other way the selecting of empty list will keep the current selection, which is not correct.

[martinez]

Even shorter. With no arrays. :)


function selectLayerPrefix str =
(
clearSelection()
for i = 1 to LayerManager.count-1 where matchPattern (LayerManager.getLayer i).name pattern:(str +"*") do (LayerManager.getLayer i).select on
)

selectLayerPrefix "Control"

[denisT]

Even shorter. With no arrays. :)


function selectLayerPrefix str =
(
clearSelection()
for i = 1 to LayerManager.count-1 where matchPattern (LayerManager.getLayer i).name pattern:(str +"*") do (LayerManager.getLayer i).select on
)

selectLayerPrefix "Control"

more selection changed callbacks than by selecting all nodes at once ;)

[LoneRobot]

In my talk at EUE the year before last I detailed a layer control script (http://lonerobot.net/?p=1239) that we used in production for many years. There are a lot of methods included that you could use for writing something similar.