PDA

View Full Version : UI Help - Three questions


PozestStar
12-09-2011, 11:03 AM
I'm reworking the 2nd MEL script I ever did. It allows the user to get a snapshot of their active view and save that snapshop as a .jpg and .gif or 15 other choices. It does this by playblasting a single frame as an image.

Anyway, I have two questions (so far, I'm sure I'll have 45309 others by the time this is done).

1) I'm getting the error "object pFormat not found" on line 56. pFormat is the name of my picture format option menu. My camera menu isn't getting an error and I set that up the same way I did the other menu. I have no idea why.

2) I have a for loop. For every camera in the scene, create an option in my option menu. I only have 1 test camera in my scene, and it's Bob_Camera. It's giving me 5 options, all named Bob_Camera. Why? I mean, even if it caught the persp, side, top and front camera, wouldn't those just appear instead of 5 Bob_Cameras?

3) I'm up blank creek without a paddle on my option menu. Am I doing this right at all? I commented it out so I could test my UI, but... I don't know. I've been reading up on option menu's for a while, but I don't know if I have a solid grasp on them yet.

I'm still working on this, but here's the section of my script that I need help with. Feel free to tear it apart.

I realize this is a lot to ask, but it's really helping. I've learned so much from everyone who's helped me. Thanks for any help you can give!


global proc takeSnapShot() {
global string $snapshotWindow;
if (`window -exists snapshotUI`){
deleteUI -window snapshotUI;
}
//Creates Snapshot Window
$snapshotWindow = `window -widthHeight 300 300 -rtf false -sizeable false -title "Take Snapshot" snapshotUI`;
columnLayout;
rowColumnLayout -numberOfRows 1;
string $fnAll = `file -q -sn`;
string $extension = ("." + fileExtension($fnAll));
string $fn = basename ($fnAll, $extension);

string $picName = `textFieldGrp
-label "Image Name:"
-ann "Name of your image"
-cw 1 100
-cw 2 200
-text $fn`;
setParent ..;

rowColumnLayout -numberOfRows 1;
string $widthField = `intFieldGrp -numberOfFields 2
-label "Width & Height:"
-ann "Width and Height of your image"
-cw 1 100
-cw 2 50
-cw 3 50
-value1 300 //$width
-value2 300`; //$height
setParent ..;

rowColumnLayout -numberOfRows 1;

global string $picExt[17]; //File Extention
global int $picExtNum[17]; //File Extention's internal value (i.e. PSD is 31)

string $picFormat = `optionMenuGrp -cw2 100 150 -label "Image Format:" -cc changeMenuCmds pFormat`;
menuItem -label "ALS"; $picExt[0] = "als"; $picExtNum[0] = 6;
menuItem -label "CIN"; $picExt[1] = "cin"; $picExtNum[1] = 11;
menuItem -label "EPS"; $picExt[2] = "eps"; $picExtNum[2] = 9;
menuItem -label "GIF"; $picExt[3] = "gif"; $picExtNum[3] = 0;
menuItem -label "JPEG"; $picExt[4] = "jpeg"; $picExtNum[4] = 8;
menuItem -label "MAYA IFF"; $picExt[5] = "iff"; $picExtNum[5] = 7;
menuItem -label "MAYA16 IFF"; $picExt[6] = "iff"; $picExtNum[6] = 10;
menuItem -label "YUV"; $picExt[7] = "yuv"; $picExtNum[7] = 12;
menuItem -label "RLA"; $picExt[8] = "rla"; $picExtNum[8] = 2;
menuItem -label "SGI"; $picExt[9] = "sgi"; $picExtNum[9] = 5;
menuItem -label "SGI16"; $picExt[10] = "sgi"; $picExtNum[10] = 13;
menuItem -label "PIC"; $picExt[11] = "pic"; $picExtNum[11] = 1;
menuItem -label "PSD"; $picExt[12] = "psd"; $picExtNum[12] = 31;
menuItem -label "TGA"; $picExt[13] = "tga"; $picExtNum[13] = 19;
menuItem -label "TIFF"; $picExt[14] = "tif"; $picExtNum[14] = 3;
menuItem -label "TIFF16"; $picExt[15] = "tif"; $picExtNum[15] = 4;
menuItem -label "BMP"; $picExt[16] = "bmp"; $picExtNum[16] = 20;
optionMenu -e -sl 5 pFormat;
setParent ..;

rowColumnLayout -numberOfRows 1;
string $camSelection[] = `listCameras`;
string $camList = `optionMenuGrp -cw2 100 150 -label "Camera Selection:" camList`;
string $cams;

for ($cams in $camSelection){
menuItem -label $camSelection;
}
setParent ..;


rowColumnLayout -numberOfColumns 3
-cw 1 150
-cw 2 150;

//Button to create snapshot
button -label "Create Snapshot" -command "fileNameChecker";
//Button to close UI
button -label "Close" -command "deleteUI -window $snapshotWindow";
setParent ..;

showWindow snapshotUI;
}
/*
global proc changeMenuCmds(){

int $formatOption = `optionMenuGrp -q -value pFormat`;

switch ($formatOption){
case "1": setAttr "defaultRenderGlobals.imageFormat" $picExtNum[0]; break;
case "2": setAttr "defaultRenderGlobals.imageFormat" $picExtNum[1]; break;
case "3": setAttr "defaultRenderGlobals.imageFormat" $picExtNum[2]; break;
case "4": setAttr "defaultRenderGlobals.imageFormat" $picExtNum[3]; break;
case "5": setAttr "defaultRenderGlobals.imageFormat" $picExtNum[4]; break;
case "6": setAttr "defaultRenderGlobals.imageFormat" $picExtNum[5]; break;
case "7": setAttr "defaultRenderGlobals.imageFormat" $picExtNum[6]; break;
case "8": setAttr "defaultRenderGlobals.imageFormat" $picExtNum[7]; break;
case "9": setAttr "defaultRenderGlobals.imageFormat" $picExtNum[8]; break;
case "10": setAttr "defaultRenderGlobals.imageFormat" $picExtNum[9]; break;
case "11": setAttr "defaultRenderGlobals.imageFormat" $picExtNum[10]; break;
case "12": setAttr "defaultRenderGlobals.imageFormat" $picExtNum[11]; break;
case "13": setAttr "defaultRenderGlobals.imageFormat" $picExtNum[12]; break;
case "14": setAttr "defaultRenderGlobals.imageFormat" $picExtNum[13]; break;
case "15": setAttr "defaultRenderGlobals.imageFormat" $picExtNum[14]; break;
case "16": setAttr "defaultRenderGlobals.imageFormat" $picExtNum[15]; break;
case "17": setAttr "defaultRenderGlobals.imageFormat" $picExtNum[16]; break;
}

}
*/

Azrail
12-09-2011, 12:59 PM
1: You are editing the optionMenuGrp, but using the optionMenu command, so Maya tries to find an optionMenu named pFormat:

string $picFormat = `optionMenuGrp -cw2 100 150 -label "Image Format:" -cc changeMenuCmds pFormat`;
....
optionMenu -e -sl 5 pFormat;

2: $cams is the camera name, $camSelection is an array so:

for ($cams in $camSelection){
// This one:
// menuItem -label $camSelection;
// should be
menuItem -label $cams;
}

3: You don't need the switch/case:

global proc changeMenuCmds(){
int $formatOption = `optionMenuGrp -q -value pFormat`;
setAttr "defaultRenderGlobals.imageFormat" $picExtNum[$formatOption - 1];
}

PozestStar
12-09-2011, 03:00 PM
Thanks so much! The last two really helped me.

As for the optionMenuGrp. I tried to use just an optionMenu, but it destoryed my entire UI. Do you know why that is?

EDIT
Nevermind, I figured it out. Thanks!

PozestStar
12-09-2011, 05:57 PM
I do have another question.

I'm getting an error saying Error: Line 83.93: "$picExtNum" is an undeclared variable. But it is declared on line 32 as global int $picExtNum[17];

Do you (or anyone else reading this thread) know why that is?

Thanks.

goleafsgo
12-10-2011, 01:41 AM
You need to make the same declaration of it inside the "changeMenuCmds". You declared it inside "takeSnapShot" but the two proc's can't see what's going on in the other.

PozestStar
12-10-2011, 09:10 AM
Thanks, but that raises another question. I thought the purpose of making something global was so that it could be used in different procedures. Am I understanding them wrong?

LoneWolf78
12-11-2011, 12:39 AM
Thanks, but that raises another question. I thought the purpose of making something global was so that it could be used in different procedures. Am I understanding them wrong?

making a global var is so that it can be used by other proc's, scripts as long as they also have that global var inside them.

it's like saying to the proc, "u can use this global var and its value that goes with it"

hope that mase some sence. lol. anyhow here's an example.



global int $myGlobalVar;

proc myProc1()
{
global int $myGlobalVar; // saying proc1 can use this global var
$myGlobalVar = 100; // setting the global var to 100
print($myGlobalVar+"\n"); // result 100
}

proc myProc2()
{
global int $myGlobalVar; // saying proc2 can use this global var
$myGlobalVar = $myGlobalVar - 25; // 100-25 because we set the value before to 100
print($myGlobalVar+"\n"); // result 100-25=75
}

myProc1;
myProc2;


hope this helps you understand.

WesHowe
12-11-2011, 03:53 AM
You are right. But by default, variables have a scope limited to the block (and all nested blocks) where it was declared. The "global" modifier on the declaration overrides that, so the first time the declaration is executed that name will be placed in the global symbol table, and values can be stored or referenced.

In the second routine, by specifying "global" on the declaration, if the symbol exists another copy isn't created, the original from the global symbol table is used. But by default, without declaring a global variable in a routine it will not be visible in that routine (and that is why you got the error).

Also take note that a global variable is really global... if one script creates a global variable "count" any other script can see and use that value, but can also change it. If you are switching between multiple scripts that use the same global symbol names this could create subtle and hard-to-find problems.

<* Wes *>

PozestStar
12-11-2011, 12:59 PM
Thanks for the explanation, it really, really helped. The more I work with global variables, the more I realize how much of a pain they are. I think this is a good project for me to get familiar with them, but after this I'm going to try to never, ever use them again.

But this raises yet ANOTHER question. I ended up doing this: (changes are at the bottom in red)


global proc takeSnapShot() {
string $snapshotWindow;
if (`window -exists snapshotUI`){
deleteUI -window snapshotUI;
}
//Creates Snapshot Window
$snapshotWindow = `window -widthHeight 300 300 -rtf false -sizeable false -title "Take Snapshot" snapshotUI`;
columnLayout;
rowColumnLayout -numberOfRows 1;
string $fnAll = `file -q -sn`;
string $extension = ("." + fileExtension($fnAll));
string $fn = basename ($fnAll, $extension);

string $picName = `textFieldGrp
-label "Image Name:"
-ann "Name of your image"
-cw 1 100
-cw 2 200
-text $fn`;
setParent ..;

rowColumnLayout -numberOfRows 1;
string $widthField = `intFieldGrp -numberOfFields 2
-label "Width & Height:"
-ann "Width and Height of your image"
-cw 1 100
-cw 2 50
-cw 3 50
-value1 300 //$width
-value2 300`; //$height
setParent ..;

rowColumnLayout -numberOfRows 1;

global string $picExt[17]; //File Extention
global int $picExtNum[17]; //File Extention's internal value (i.e. PSD is 31)

string $picFormat = `optionMenuGrp -cw2 100 150 -label "Image Format:" -cc changeMenuCmds pFormat`;
menuItem -label "ALS"; $picExt[0] = "als"; $picExtNum[0] = 6;
menuItem -label "CIN"; $picExt[1] = "cin"; $picExtNum[1] = 11;
menuItem -label "EPS"; $picExt[2] = "eps"; $picExtNum[2] = 9;
menuItem -label "GIF"; $picExt[3] = "gif"; $picExtNum[3] = 0;
menuItem -label "JPEG"; $picExt[4] = "jpeg"; $picExtNum[4] = 8;
menuItem -label "MAYA IFF"; $picExt[5] = "iff"; $picExtNum[5] = 7;
menuItem -label "MAYA16 IFF"; $picExt[6] = "iff"; $picExtNum[6] = 10;
menuItem -label "YUV"; $picExt[7] = "yuv"; $picExtNum[7] = 12;
menuItem -label "RLA"; $picExt[8] = "rla"; $picExtNum[8] = 2;
menuItem -label "SGI"; $picExt[9] = "sgi"; $picExtNum[9] = 5;
menuItem -label "SGI16"; $picExt[10] = "sgi"; $picExtNum[10] = 13;
menuItem -label "PIC"; $picExt[11] = "pic"; $picExtNum[11] = 1;
menuItem -label "PSD"; $picExt[12] = "psd"; $picExtNum[12] = 31;
menuItem -label "TGA"; $picExt[13] = "tga"; $picExtNum[13] = 19;
menuItem -label "TIFF"; $picExt[14] = "tif"; $picExtNum[14] = 3;
menuItem -label "TIFF16"; $picExt[15] = "tif"; $picExtNum[15] = 4;
menuItem -label "BMP"; $picExt[16] = "bmp"; $picExtNum[16] = 20;
optionMenuGrp -e -sl 5 pFormat;
setParent ..;

rowColumnLayout -numberOfRows 1;
string $camSelection[] = `listCameras`;
string $camList = `optionMenuGrp -cw2 100 150 -label "Camera Selection:" camList`;
string $cams;

for ($cams in $camSelection){
menuItem -label $cams;
}
setParent ..;


rowColumnLayout -numberOfColumns 3
-cw 1 150
-cw 2 150;

//Button to create snapshot
button -label "Create Snapshot" -command "fileNameChecker";
//Button to close UI
button -label "Close" -command "deleteUI -window $snapshotWindow";
setParent ..;

changeMenuCmds($picExt, $picExtNum);
showWindow snapshotUI;

}

global proc changeMenuCmds(string $picExt[], int $picExtNum[]){
int $formatOption = `optionMenuGrp -q -value pFormat`;
setAttr "defaultRenderGlobals.imageFormat" $picExtNum[$formatOption - 1];
}


Proud. That's the first time I've ever passed arguments and it works! ...I think. But I'm getting two new errors.

// Warning: line 86: Converting string "JPEG" to an int value of 0. // // Error: line 87: Invalid negative index used to reference array "$picExtNum". //



Does anyone know why this is happening and/or how to fix it? I don't even know what this error means.

WesHowe
12-11-2011, 05:30 PM
The following expression:
$picExtNum[$formatOption - 1];
will blow up if $formatOption is zero.

<* Wes *>

PozestStar
12-11-2011, 07:22 PM
Thanks. That makes sense.

PozestStar
12-12-2011, 01:37 AM
Record for asking the most questions in a day goes to me :applause:

I fixed all of the above, only to get the warning:
Warning: line 103: Converting string "JPEG" to an int value of 0.

When I switch image formats in my option menu, I get the error.
Wrong number of arguments on call to changeMenuCmds.I get the feeling it's because I haven't passed an argument to my changeMenuCmds procedure, but do I have to? I don't even know what it would take. Does anyone see what's wrong? Again, thanks SO MUCH for your help! The information I've gotten here has helped me fix the rest of the script and I couldn't have done it without this information.

The code so far:


global proc takeSnapShot() {
string $snapshotWindow;
if (`window -exists snapshotUI`){
deleteUI -window snapshotUI;
}
//Creates Snapshot Window
$snapshotWindow = `window -widthHeight 300 300 -rtf false -sizeable false -title "Take Snapshot" snapshotUI`;
columnLayout;
rowColumnLayout -numberOfRows 1;
string $fnAll = `file -q -sn`;
string $extension = ("." + fileExtension($fnAll));
string $fn = basename ($fnAll, $extension);

string $picName = `textFieldGrp
-label "Image Name:"
-ann "Name of your image"
-cw 1 100
-cw 2 200
-text $fn`;
setParent ..;

rowColumnLayout -numberOfRows 1;
string $widthField = `intFieldGrp -numberOfFields 2
-label "Width & Height:"
-ann "Width and Height of your image"
-cw 1 100
-cw 2 50
-cw 3 50
-value1 300 //$width
-value2 300`; //$height
setParent ..;

rowColumnLayout -numberOfRows 1;

global string $picExt[17]; //File Extention
global int $picExtNum[17]; //File Extention's internal value (i.e. PSD is 31)

string $picFormat = `optionMenuGrp -cw2 100 150 -label "Image Format:" -cc changeMenuCmds pFormat`;
menuItem -label "ALS"; $picExt[0] = "als"; $picExtNum[0] = 6;
menuItem -label "CIN"; $picExt[1] = "cin"; $picExtNum[1] = 11;
menuItem -label "EPS"; $picExt[2] = "eps"; $picExtNum[2] = 9;
menuItem -label "GIF"; $picExt[3] = "gif"; $picExtNum[3] = 0;
menuItem -label "JPEG"; $picExt[4] = "jpeg"; $picExtNum[4] = 8;
menuItem -label "MAYA IFF"; $picExt[5] = "iff"; $picExtNum[5] = 7;
menuItem -label "MAYA16 IFF"; $picExt[6] = "iff"; $picExtNum[6] = 10;
menuItem -label "YUV"; $picExt[7] = "yuv"; $picExtNum[7] = 12;
menuItem -label "RLA"; $picExt[8] = "rla"; $picExtNum[8] = 2;
menuItem -label "SGI"; $picExt[9] = "sgi"; $picExtNum[9] = 5;
menuItem -label "SGI16"; $picExt[10] = "sgi"; $picExtNum[10] = 13;
menuItem -label "PIC"; $picExt[11] = "pic"; $picExtNum[11] = 1;
menuItem -label "PSD"; $picExt[12] = "psd"; $picExtNum[12] = 31;
menuItem -label "TGA"; $picExt[13] = "tga"; $picExtNum[13] = 19;
menuItem -label "TIFF"; $picExt[14] = "tif"; $picExtNum[14] = 3;
menuItem -label "TIFF16"; $picExt[15] = "tif"; $picExtNum[15] = 4;
menuItem -label "BMP"; $picExt[16] = "bmp"; $picExtNum[16] = 20;
optionMenuGrp -e -sl 5 pFormat;
setParent ..;

rowColumnLayout -numberOfRows 1;
string $camSelection[] = `listCameras`;
string $camList = `optionMenuGrp -cw2 100 150 -label "Camera Selection:" camList`;
string $cams;

for ($cams in $camSelection){
menuItem -label $cams;
}
setParent ..;


rowColumnLayout -numberOfColumns 3
-cw 1 150
-cw 2 150;

//Button to create snapshot
button -label "Create Snapshot" -command "fileNameChecker";
//Button to close UI
button -label "Close" -command "deleteUI -window $snapshotWindow";
setParent ..;

changeMenuCmds($picExt, $picExtNum);
showWindow snapshotUI;

}

global proc changeMenuCmds(string $picExt[], int $picExtNum[]){

int $formatOption = `optionMenuGrp -q -value pFormat`;
setAttr "defaultRenderGlobals.imageFormat" $picExtNum[$formatOption];
}

WesHowe
12-12-2011, 09:56 AM
You are not using "string $picExt[]" at all in your changeMenuCmds() function. So you could reduce that to passing a single argument.

I noticed that you are still declaring these variables as global:
global string $picExt[17]; //File Extention
global int $picExtNum[17]; //File Extention's internal value (i.e. PSD is 31)

You should not need to declare them as $picExt[17], $picExt[] should do. MEL manages the array sizing based on how it is used, so later, you can make the assignment:
$picExt[10] = "sgi";
and it should work fine.

I'm not sure I can help any further tonight, I am well past a reasonable time to go to bed. To do more I would need to copy the script to my machine and experiment with it... the UI stuff I avoid when I can, and I am getting darn good at it (avoidance) so some of the stuff there fades without regular usage.

If no one else from the other side of the world fixes it all up for you, I will try to look here tomorrow earlier and see what I can do.

<* Wes *>

Azrail
12-12-2011, 01:51 PM
That's what the other side of the world can offer for now ;) :

global proc takeSnapShot() {
string $snapshotWindow;
if (`window -exists snapshotUI`){
deleteUI -window snapshotUI;
}
//Creates Snapshot Window
$snapshotWindow = `window -widthHeight 300 300 -rtf false -sizeable false -title "Take Snapshot" snapshotUI`;
columnLayout;
rowColumnLayout -numberOfRows 1;
string $fnAll = `file -q -sn`;
string $extension = ("." + fileExtension($fnAll));
string $fn = basename ($fnAll, $extension);

string $picName = `textFieldGrp
-label "Image Name:"
-ann "Name of your image"
-cw 1 100
-cw 2 200
-text $fn`;
setParent ..;

rowColumnLayout -numberOfRows 1;
string $widthField = `intFieldGrp -numberOfFields 2
-label "Width & Height:"
-ann "Width and Height of your image"
-cw 1 100
-cw 2 50
-cw 3 50
-value1 300 //$width
-value2 300`; //$height
setParent ..;

rowColumnLayout -numberOfRows 1;

global string $picExt[17]; //File Extention
global int $picExtNum[17]; //File Extention's internal value (i.e. PSD is 31)

string $picFormat = `optionMenuGrp -cw2 100 150 -label "Image Format:" pFormat`;
menuItem -label "ALS"; $picExt[0] = "als"; $picExtNum[0] = 6;
menuItem -label "CIN"; $picExt[1] = "cin"; $picExtNum[1] = 11;
menuItem -label "EPS"; $picExt[2] = "eps"; $picExtNum[2] = 9;
menuItem -label "GIF"; $picExt[3] = "gif"; $picExtNum[3] = 0;
menuItem -label "JPEG"; $picExt[4] = "jpeg"; $picExtNum[4] = 8;
menuItem -label "MAYA IFF"; $picExt[5] = "iff"; $picExtNum[5] = 7;
menuItem -label "MAYA16 IFF"; $picExt[6] = "iff"; $picExtNum[6] = 10;
menuItem -label "YUV"; $picExt[7] = "yuv"; $picExtNum[7] = 12;
menuItem -label "RLA"; $picExt[8] = "rla"; $picExtNum[8] = 2;
menuItem -label "SGI"; $picExt[9] = "sgi"; $picExtNum[9] = 5;
menuItem -label "SGI16"; $picExt[10] = "sgi"; $picExtNum[10] = 13;
menuItem -label "PIC"; $picExt[11] = "pic"; $picExtNum[11] = 1;
menuItem -label "PSD"; $picExt[12] = "psd"; $picExtNum[12] = 31;
menuItem -label "TGA"; $picExt[13] = "tga"; $picExtNum[13] = 19;
menuItem -label "TIFF"; $picExt[14] = "tif"; $picExtNum[14] = 3;
menuItem -label "TIFF16"; $picExt[15] = "tif"; $picExtNum[15] = 4;
menuItem -label "BMP"; $picExt[16] = "bmp"; $picExtNum[16] = 20;
optionMenuGrp -e -sl 5 pFormat;
setParent ..;

rowColumnLayout -numberOfRows 1;
string $camSelection[] = `listCameras`;
string $camList = `optionMenuGrp -cw2 100 150 -label "Camera Selection:" camList`;
string $cams;

for ($cams in $camSelection){
menuItem -label $cams;
}
setParent ..;


rowColumnLayout -numberOfColumns 3
-cw 1 150
-cw 2 150;

//Button to create snapshot
button -label "Create Snapshot" -command "fileNameChecker";
//Button to close UI
button -label "Close" -command "deleteUI -window $snapshotWindow";
setParent ..;
optionMenuGrp -e -cc ("changeMenuCmds $picExt $picExtNum") pFormat;
changeMenuCmds($picExt, $picExtNum);
showWindow snapshotUI;

}

global proc changeMenuCmds(string $picExt[], int $picExtNum[]){

int $formatOption = `optionMenuGrp -q -sl pFormat`;
setAttr "defaultRenderGlobals.imageFormat" $picExtNum[$formatOption];
}
//takeSnapShot

First of all you will need to pass both arrays as arguments, so you better assign the change command after they (the arrays) are filled with needed data. About the error: you need to use the -select/-sl query flag for the option menu to get the index of the item, now you use -value, which returns the selected item's text.

PozestStar
12-12-2011, 06:36 PM
:cry: Tears of joy. I love you guys! Your suggestions worked!

I thought of querying the selection too when I noticed that optionMenuGrp didn't have a value flag (oops lol). But I had no idea that you could assign the change command after doing something. That really helped, especially with something else I'm working on.

I also changed changed the picExt[17] to picExt [] (the same with the other int), and I just started everything off at 1 instead of 0. It's made life so much easier.

Thanks again! :)

WesHowe
12-12-2011, 10:47 PM
Well, I am happy you have this going. I was thinking of Oz when I mentioned "the other side of the world", but it is a long way from here to Bulgaria (or anywhere at all, for that matter... Texas is made of miles).

<* Wes *>

CGTalk Moderation
12-12-2011, 10:47 PM
This thread has been automatically closed as it remained inactive for 12 months. If you wish to continue the discussion, please create a new thread in the appropriate forum.